Working version of postgresql::server

This is a first working version of postgresql::server.
It includes a very simple test manifest, which has
been tried out on CentOS6 and Ubuntu 10.04; initial
tests were successful both from a clean state and
for subsequent runs.

Includes a new fact called 'postgres_default_version',
which detects what the default version of postgres is
for a given OS.  This is needed because some of the
commands and directory names include this version string.

Current implementation *only* supports managing the
system default version; in the future it would be nice
to allow the user to explicitly specify a postgres version,
but that isn't yet supported.

The "postgresql::server" class includes a call to postgres's
initdb command on redhat systems, because they don't do
this automatically when the package is installed.

Author: cprice404

lib/facter/postgres_default_version.rb

@@ -0,0 +1,30 @@
+def get_debian_postgres_version
+  depends = Facter::Util::Resolution.exec('apt-cache show postgresql |grep "^Depends" |head -n 1')
+  if match = /^Depends: postgresql-(.*)$/.match(depends)
+    match[1]
+  else
+    nil
+  end
+end
+
+def get_redhat_postgres_version
+  version = Facter::Util::Resolution.exec('yum info postgresql-server |grep "^Version"')
+  if match = /^Version\s*:\s*(\d+\.\d+).*$/.match(version)
+    match[1]
+  else
+    nil
+  end
+end
+
+Facter.add("postgres_default_version") do
+  setcode do
+    case Facter.value('osfamily')
+      when 'RedHat'
+        get_redhat_postgres_version()
+      when 'Debian'
+        get_debian_postgres_version()
+      else
+        nil
+    end
+  end
+end

manifests/init.pp

@@ -0,0 +1,24 @@
+# Class: postgresql
+#
+#   This class installs postgresql client software.
+#
+# Parameters:
+#   [*client_package_name*]  - The name of the postgresql client package.
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class postgresql (
+  $package_name   = $postgresql::params::client_package_name,
+  $package_ensure = 'present'
+) inherits postgresql::params {
+
+  package { 'postgresql_client':
+    name    => $package_name,
+    ensure  => $package_ensure,
+  }
+
+}

manifests/initdb.pp

@@ -16,20 +16,18 @@
 # See the License for the specific language governing permissions and
 # limitations under the License.
 
-define postgresql::initdb(
-  $directory = $title,
-  $version = '9.1',
+class postgresql::initdb(
+  $datadir = $postgresql::params::datadir,
+  $initdb_path = $postgresql::params::initdb_path,
   $user = 'postgres',
   $group = 'postgres',
   $encoding = 'UTF8',
-  $options='') {
+  $options=''
+) inherits postgresql::params {
 
-  # TODO: This should be found based on the operating system; currently hardcoded to Ubuntu's path choice
-  exec {"/usr/lib/postgresql/${version}/bin/initdb --encoding '$encoding' --pgdata '$directory'":
-    command => "/usr/lib/postgresql/${version}/bin/initdb --encoding '$encoding' --pgdata '$directory'",
-    creates => "$directory",
+  exec {"${initdb_path} --encoding '$encoding' --pgdata '$datadir'":
+    creates => "${datadir}/PG_VERSION",
     user    => "$user",
     group   => "$group",
-    require => Package["postgresql-$version"],
   }
 }

manifests/params.pp

@@ -0,0 +1,49 @@
+# Class: postgresql::params
+#
+#   The postgresql configuration settings.
+#
+# Parameters:
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class postgresql::params {
+
+  case $::operatingsystem {
+    "Ubuntu": {
+      $service_provider = upstart
+    }
+    default: {
+      $service_provider = undef
+    }
+  }
+
+  case $::osfamily {
+    'RedHat': {
+      $service_name          = 'postgresql'
+      $client_package_name   = 'postgresql'
+      $server_package_name   = 'postgresql-server'
+      $needs_initdb          = true
+      $initdb_path           = '/usr/bin/initdb'
+      $datadir               = '/var/lib/pgsql/data/'
+    }
+
+    'Debian': {
+      $service_name         = "postgresql-${::postgres_default_version}"
+      $client_package_name  = 'postgresql-client'
+      $server_package_name  = 'postgresql'
+      $needs_initdb         = false
+      $initdb_path          = "/usr/lib/postgresql/${::postgres_default_version}/bin/initdb"
+      $datadir              = "/var/lib/postgresql/${::postgres_default_version}/main"
+    }
+
+
+    default: {
+      fail("Unsupported osfamily: ${::osfamily} operatingsystem: ${::operatingsystem}, module ${module_name} currently only supports osfamily RedHat and Debian")
+    }
+  }
+
+}

manifests/server.pp

@@ -0,0 +1,43 @@
+# Class: postgresql::server
+#
+# manages the installation of the postgresql server.  manages the package and service
+#
+# Parameters:
+#   [*package_name*] - name of package
+#   [*service_name*] - name of service
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class postgresql::server (
+  $package_name     = $postgresql::params::server_package_name,
+  $package_ensure   = 'present',
+  $service_name     = $postgresql::params::service_name,
+  $service_provider = $postgresql::params::service_provider,
+  $config_hash      = {}
+) inherits postgresql::params {
+
+  package { 'postgresql-server':
+    name   => $package_name,
+    ensure => $package_ensure,
+  }
+
+  if ($needs_initdb) {
+    include postgresql::initdb
+
+    Class['postgresql::initdb'] -> Service['postgresqld']
+  }
+
+  service { 'postgresqld':
+    name     => $service_name,
+    ensure   => running,
+    enable   => true,
+    require  => Package['postgresql-server'],
+    provider => $service_provider,
+  }
+
+
+}

tests/init.pp

@@ -0,0 +1 @@
+include postgresql

tests/server.pp

@@ -0,0 +1,2 @@
+class { 'postgresql::server':
+}