Add Flower decoration scene

This is a flavour of Decoration which chooses a random texture from a
series of directories. The files in those directories are the flowers
(and a mushroom) that are currently manually placed in Fray's End, plus
a new flower drawn by a learner (who agrees to license it under
CC-BY-SA-4.0, as does their adult (me)).

The random selection is done based on the node's path in the scene,
which means that the choice will remain the same between runs so long as
the list remains the same.

#556

Author: wjt

scenes/game_elements/props/decoration/flower/assets/lcjt-flower.png

@@ -0,0 +1,34 @@
+[remap]
+
+importer="texture"
+type="CompressedTexture2D"
+uid="uid://dt4lx6310tcoy"
+path="res://.godot/imported/lcjt-flower.png-d6fabfbb70fcabe42e0f32acab468c79.ctex"
+metadata={
+"vram_texture": false
+}
+
+[deps]
+
+source_file="res://scenes/game_elements/props/decoration/flower/assets/lcjt-flower.png"
+dest_files=["res://.godot/imported/lcjt-flower.png-d6fabfbb70fcabe42e0f32acab468c79.ctex"]
+
+[params]
+
+compress/mode=0
+compress/high_quality=false
+compress/lossy_quality=0.7
+compress/hdr_compression=1
+compress/normal_map=0
+compress/channel_pack=0
+mipmaps/generate=false
+mipmaps/limit=-1
+roughness/mode=0
+roughness/src_normal=""
+process/fix_alpha_border=true
+process/premult_alpha=false
+process/normal_map_invert_y=false
+process/hdr_as_srgb=false
+process/hdr_clamp_exposure=false
+process/size_limit=0
+detect_3d/compress_to=1

scenes/game_elements/props/decoration/flower/assets/lcjt-flower.png.import

@@ -0,0 +1,67 @@
+# SPDX-FileCopyrightText: The Threadbare Authors
+# SPDX-License-Identifier: MPL-2.0
+@tool
+class_name Flower
+extends Decoration
+## A decoration which deterministically picks its texture from a hardcoded list of directories.
+##
+## The goal here is to be able to add new flowers to a flowerbed in Fray's End by adding a file to
+## the repository, without touching any scene in a conflict-prone way.
+
+const TEXTURE_DIRECTORIES := [
+	"res://scenes/game_elements/props/decoration/crochenthemum/",
+	"res://scenes/game_elements/props/decoration/mushroom/",
+	"res://scenes/game_elements/props/decoration/flower/assets/",
+]
+static var _textures: Array[Texture2D]
+
+
+static func _load_textures_from(directory_path: String) -> void:
+	var files := ResourceLoader.list_directory(directory_path)
+	files.sort()
+	for file: String in files:
+		var path := directory_path.path_join(file)
+		var resource := ResourceLoader.load(path)
+		if resource is Texture2D:
+			_textures.append(resource)
+		else:
+			push_warning("%s is not a Texture2D" % path)
+
+
+# Initialises the static _textures list, if not already done
+static func _initialise_textures() -> void:
+	if _textures:
+		return
+
+	for directory_path: String in TEXTURE_DIRECTORIES:
+		_load_textures_from(directory_path)
+
+
+func _validate_property(property: Dictionary) -> void:
+	if property.name == "texture":
+		# Prevent modifying texture property in inspector: it would be re-set next time the scene
+		# loads.
+		property.usage |= PROPERTY_USAGE_READ_ONLY
+		property.usage |= PROPERTY_USAGE_NO_INSTANCE_STATE
+
+		# Don't store the texture in the scene file: it would be overwritten when new flower images
+		# are added.
+		property.usage &= ~PROPERTY_USAGE_STORAGE
+
+
+func _init() -> void:
+	_initialise_textures()
+
+
+func _enter_tree() -> void:
+	# Assign a texture to this instance of the flower, in a fashion that is deterministic so long
+	# as the set of flowers does not change.
+	var tree := get_tree()
+	var current_scene := tree.edited_scene_root if Engine.is_editor_hint() else tree.current_scene
+
+	# Don't save a texture in flower.tscn's Sprite2D
+	if Engine.is_editor_hint() and self == current_scene:
+		return
+
+	var path := current_scene.get_path_to(self)
+	texture = _textures[path.hash() % _textures.size()]

scenes/game_elements/props/decoration/flower/components/flower.gd

@@ -0,0 +1 @@
+uid://eenl0b7aoxuq

scenes/game_elements/props/decoration/flower/components/flower.gd.uid

@@ -0,0 +1,9 @@
+[gd_scene load_steps=2 format=3 uid="uid://c0104ickpm3ru"]
+
+[ext_resource type="Script" uid="uid://eenl0b7aoxuq" path="res://scenes/game_elements/props/decoration/flower/components/flower.gd" id="1_8t1d6"]
+
+[node name="Flower" type="Node2D"]
+script = ExtResource("1_8t1d6")
+
+[node name="Sprite2D" type="Sprite2D" parent="."]
+unique_name_in_owner = true