Add JzAzBz "color space"

Author: Filoppi

Shaders/Includes/Color.hlsl

@@ -398,7 +398,8 @@ static const float PQ_constant_C2 = 18.8515625f;
 static const float PQ_constant_C3 = 18.6875f;
 
 // PQ (Perceptual Quantizer - ST.2084) encode/decode used for HDR10 BT.2100.
-float3 Linear_to_PQ(float3 LinearColor, int clampType = GCT_DEFAULT)
+// Input is expected to be pre-normalized in 0-1 range, supposedly, but not necessarily in the HDR10 range ("HDR10_MaxWhiteNits").
+float3 Linear_to_PQ(float3 LinearColor, int clampType = GCT_DEFAULT, float Exponent = 1.0)
 {
 	float3 LinearColorSign = sign(LinearColor);
 	if (clampType == GCT_POSITIVE)
@@ -410,13 +411,13 @@ float3 Linear_to_PQ(float3 LinearColor, int clampType = GCT_DEFAULT)
 	float3 colorPow = pow(LinearColor, PQ_constant_M1);
 	float3 numerator = PQ_constant_C1 + PQ_constant_C2 * colorPow;
 	float3 denominator = 1.f + PQ_constant_C3 * colorPow;
-	float3 pq = pow(numerator / denominator, PQ_constant_M2);
+	float3 pq = pow(numerator / denominator, PQ_constant_M2 * Exponent);
 	if (clampType == GCT_MIRROR)
 		return pq * LinearColorSign;
 	return pq;
 }
 
-float3 PQ_to_Linear(float3 ST2084Color, int clampType = GCT_DEFAULT)
+float3 PQ_to_Linear(float3 ST2084Color, int clampType = GCT_DEFAULT, float Exponent = 1.0)
 {
 	float3 ST2084ColorSign = sign(ST2084Color);
 	if (clampType == GCT_POSITIVE)
@@ -425,7 +426,7 @@ float3 PQ_to_Linear(float3 ST2084Color, int clampType = GCT_DEFAULT)
 		ST2084Color = saturate(ST2084Color);
 	else if (clampType == GCT_MIRROR)
 		ST2084Color = abs(ST2084Color);
-	float3 colorPow = pow(ST2084Color, 1.f / PQ_constant_M2);
+	float3 colorPow = pow(ST2084Color, 1.f / (PQ_constant_M2 * Exponent));
 	float3 numerator = max(colorPow - PQ_constant_C1, 0.f);
 	float3 denominator = PQ_constant_C2 - (PQ_constant_C3 * colorPow);
 	float3 linearColor = pow(numerator / denominator, 1.f / PQ_constant_M1);

Shaders/Includes/DarktableUCS.hlsl

@@ -372,8 +372,8 @@ namespace DarktableUcs
   {
     float3 XYZ = CieXYZ::RGBTo::XZY(rgb);
     s_xyY xyY = CieXYZ::XYZTo::xyY(XYZ);
-    float3 JCH = xyYTo::LUV(xyY);
-    return JCH;
+    float3 UCSLUV = xyYTo::LUV(xyY);
+    return UCSLUV;
   }
 
   // scRGB/BT.709

Shaders/Includes/JzAzBz.hlsl

@@ -0,0 +1,78 @@
+#ifndef SRC_JZAZBZ_HLSL
+#define SRC_JZAZBZ_HLSL
+
+#include "Color.hlsl"
+
+// -----------------------------------------------------------------------------
+// Jzazbz
+// 
+// Reference:
+// Muhammad Safdar, Guihua Cui, Youn Jin Kim, and Ming Ronnier Luo,
+// "Perceptually uniform color space for image signals including high dynamic
+// range and wide gamut," Opt. Express 25, 15131-15151 (2017)
+// -----------------------------------------------------------------------------
+namespace JzAzBz
+{
+    #define JZAZBZ_EXPONENT_SCALE_FACTOR 1.7f // Scale factor for exponent
+
+    // Input: linear rgb with a paper white of ~100 nits (SDR neutral)
+    // Jz Luminance-like
+    // Az Red–Green opponent axis
+    // Bz Blue–Yellow opponent axis
+    float3 rgbToJzazbz(float3 rgb, uint colorSpace = CS_DEFAULT)
+    {
+        // The matrix below is for BT.2020 input.
+        // The transforms should fold with the ones below when compiled.
+        if (colorSpace == CS_BT709)
+        {
+            rgb = BT709_To_BT2020(rgb);
+        }
+        else if (colorSpace == CS_AP1)
+        {
+            rgb = float3(1, 0, 1); // Not done
+        }
+
+        float3 lms;
+        lms.x = rgb[0] * 0.530004f + rgb[1] * 0.355704f + rgb[2] * 0.086090f;
+        lms.y = rgb[0] * 0.289388f + rgb[1] * 0.525395f + rgb[2] * 0.157481f;
+        lms.z = rgb[0] * 0.091098f + rgb[1] * 0.147588f + rgb[2] * 0.734234f;
+
+        float3 lmsPQ = Linear_to_PQ(lms / (HDR10_MaxWhiteNits / Rec709_WhiteLevelNits), GCT_MIRROR, JZAZBZ_EXPONENT_SCALE_FACTOR);
+
+        float iz = 0.5f * lmsPQ.x + 0.5f * lmsPQ.y;
+
+        float3 jab;
+        jab.x = (0.44f * iz) / (1.0f - 0.56f * iz) - 1.6295499532821566e-11f;
+        jab.y = 3.524000f * lmsPQ.x - 4.066708f * lmsPQ.y + 0.542708f * lmsPQ.z;
+        jab.z = 0.199076f * lmsPQ.x + 1.096799f * lmsPQ.y - 1.295875f * lmsPQ.z;
+        return jab;
+    }
+
+    // Output: linear rgb
+    float3 jzazbzToRgb(float3 jab, uint colorSpace = CS_DEFAULT)
+    {
+        float jz = jab[0] + 1.6295499532821566e-11f;
+        float iz = jz / (0.44f + 0.56f * jz);
+        float a  = jab[1];
+        float b  = jab[2];
+
+        float3 lms;
+        lms.x = iz + a * 1.386050432715393e-1f + b * 5.804731615611869e-2f;
+        lms.y = iz + a * -1.386050432715393e-1f + b * -5.804731615611869e-2f;
+        lms.z = iz + a * -9.601924202631895e-2f + b * -8.118918960560390e-1f;
+
+        float3 lmsLin = PQ_to_Linear(lms, GCT_MIRROR, JZAZBZ_EXPONENT_SCALE_FACTOR) * (HDR10_MaxWhiteNits / Rec709_WhiteLevelNits);
+
+        float3 rgb;
+        rgb.x = lmsLin.x * 2.990669f + lmsLin.y * -2.049742f + lmsLin.z * 0.088977f;
+        rgb.y = lmsLin.x * -1.634525f + lmsLin.y * 3.145627f + lmsLin.z * -0.483037f;
+        rgb.z = lmsLin.x * -0.042505f + lmsLin.y * -0.377983f + lmsLin.z * 1.448019f;
+        if (colorSpace == CS_BT709)
+        {
+            rgb = BT2020_To_BT709(rgb);
+        }
+        return rgb;
+    }
+}
+
+#endif // SRC_JZAZBZ_HLSL

Source/Core/utils/resource.hpp

@@ -912,6 +912,7 @@ bool CopyBuffer(com_ptr<ID3D11Buffer> cb, ID3D11DeviceContext* native_device_con
    }
 
    D3D11_MAPPED_SUBRESOURCE mapped = {};
+   // Map in DX11 here can seemengly be done on deferred contexts too, it will stall the CPU until the GPU has the latest values (no need to flush the command list)
    HRESULT hr = native_device_context->Map(cb.get(), 0, D3D11_MAP_READ, 0, &mapped);
    if (FAILED(hr))
    {